Convert to autoconf 2.59. Delete junk from past centuries.

1 files changed, 74 insertions, 0 deletions

diff --git a/configure.ac b/configure.ac
new file mode 100644
index 0000000..6851626
--- /dev/null
+++ b/configure.ac
@@ -0,0 +1,74 @@
+AC_PREREQ(2.59)
+AC_INIT(ax25-tools, 0.0.9, linux-hams@vger.kernel.org)
+AC_CONFIG_SRCDIR(ax25/ax25d.c)
+AM_INIT_AUTOMAKE
+
+AM_CONFIG_HEADER(config.h)
+
+dnl Checks for programs.
+AC_PROG_AWK
+AC_PROG_CC
+AC_PROG_CXX
+AC_PROG_INSTALL
+
+dnl Check for X and set a conditional
+AC_PATH_XTRA
+AM_CONDITIONAL(HAVE_X, test -z "$no_x")
+
+dnl Checks for libraries.
+AC_SUBST(Z_LIB)
+AC_SUBST(AX25_LIB)
+AC_SUBST(AX25IO_LIB)
+AC_SUBST(NCURSES_LIB)
+AC_SUBST(UTIL_LIB)
+AC_SUBST(FLTK_LIB)
+AC_CHECK_LIB(z, zlibVersion,Z_LIB="-lz",Z_LIB=)
+AC_CHECK_LIB(ax25, ax25_config_load_ports, AX25_LIB="-lax25", AC_MSG_ERROR(Could not find the libax25 libraries; aborting))
+AC_CHECK_LIB(ncurses, initscr,NCURSES_LIB="-lncurses",NCURSES_LIB=)
+AC_CHECK_LIB(util, openpty, UTIL_LIB="-lutil",UTIL_LIB=)
+AC_CHECK_LIB(GL, main, GL_LIB="-lGL",
+  AC_CHECK_LIB(MesaGL, main, GL_LIB="-lMesaGL", GL_LIB=, ${X_LIBS} ${X_PRE_LIBS} -lXi -lXext -lX11 ${X_EXTRA_LIBS}),${X_LIBS} ${X_PRE_LIBS} -lXi -lXext -lX11 ${X_EXTRA_LIBS})
+if test -n "$GL_LIB"; then
+  AC_CHECK_LIB(fltk, main, FLTK_LIB="-lfltk $GL_LIB $X_PRE_LIBS -lXi -lXext -lX11 $X_EXTRA_LIBS", FLTK_LIB=, ${GL_LIB} ${X_LIBS} ${X_PRE_LIBS} -lXi -lXext -lX11 ${X_EXTRA_LIBS})
+fi
+AM_CONDITIONAL(HAVE_FLTK, test -n "$FLTK_LIB" )
+
+
+dnl Checks for header files.
+dnl AC_PATH_X
+AC_HEADER_STDC
+AC_HEADER_SYS_WAIT
+AC_CHECK_HEADERS(fcntl.h limits.h paths.h strings.h sys/file.h sys/ioctl.h sys/time.h syslog.h unistd.h zlib.h )
+
+dnl Checks for working glibc 2.1 headers
+AC_MSG_CHECKING(for working netax25/ax25.h header file)
+AC_EGREP_HEADER(ax25_fwd_struct, netax25/ax25.h,AC_DEFINE(HAVE_NETAX25_AX25_H, 1, [Define if you have a proper netax25/ax25.h header file.]) AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
+AC_MSG_CHECKING(for working netrom/netrom.h header file)
+AC_EGREP_HEADER(unsigned int ndigis, netrom/netrom.h,AC_DEFINE(HAVE_NETROM_NETROM_H, 1, [Define if you have a proper netrom/netrom.h header file.]) AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
+AC_MSG_CHECKING(for working netrose/rose.h header file)
+AC_EGREP_HEADER(rose_facilities_struct, netrose/rose.h,AC_DEFINE(HAVE_NETROSE_ROSE_H, 1, [Define if you have a proper netrose/rose.h header file.]) AC_MSG_RESULT(yes), AC_MSG_RESULT(no))
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_C_CONST
+AC_TYPE_UID_T
+AC_TYPE_PID_T
+AC_HEADER_TIME
+AC_STRUCT_TM
+
+dnl Checks for library functions.
+AC_PROG_GCC_TRADITIONAL
+AC_FUNC_MEMCMP
+AC_FUNC_SETPGRP
+AC_TYPE_SIGNAL
+AC_FUNC_STRFTIME
+AC_FUNC_WAIT3
+AC_CHECK_FUNCS(gethostname gettimeofday mkdir select socket strdup strerror strspn strstr strtol strtoul uname)
+
+dnl Only use -Wall if we have gcc
+if test "x$GCC" = "xyes"; then
+  if test -z "`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
+    CFLAGS="$CFLAGS -Wall"
+  fi
+fi
+
+AC_OUTPUT(netrom/Makefile tcpip/Makefile ax25/Makefile ax25/axgetput/Makefile Makefile rose/Makefile user_call/Makefile kiss/Makefile 6pack/Makefile hdlcutil/Makefile hdlcutil/fl/Makefile yamdrv/Makefile dmascc/Makefile)