1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
/*
* __put_user functions.
*
* (C) Copyright 1998 Linus Torvalds
*
* These functions have a non-standard call interface
* to make them more efficient.
*/
/*
* __put_user_X
*
* Inputs: %eax contains the address
* %edx contains the value
*
* Outputs: %eax is error code (0 or -EFAULT)
* %ecx is corrupted (will contain "current_task").
*
* These functions should not modify any other registers,
* as they get called from within inline assembly.
*/
addr_limit = 12
.text
.align 4
.globl __put_user_1
__put_user_1:
movl %esp,%ecx
andl $0xffffe000,%ecx
cmpl addr_limit(%ecx),%eax
jae bad_put_user
1: movb %dl,(%eax)
xorl %eax,%eax
ret
.align 4
.globl __put_user_2
__put_user_2:
addl $1,%eax
movl %esp,%ecx
jc bad_put_user
andl $0xffffe000,%ecx
cmpl addr_limit(%ecx),%eax
jae bad_put_user
2: movw %dx,-1(%eax)
xorl %eax,%eax
ret
.align 4
.globl __put_user_4
__put_user_4:
addl $3,%eax
movl %esp,%ecx
jc bad_put_user
andl $0xffffe000,%ecx
cmpl addr_limit(%ecx),%eax
jae bad_put_user
3: movl %edx,-3(%eax)
xorl %eax,%eax
ret
bad_put_user:
movl $-14,%eax
ret
.section __ex_table,"a"
.long 1b,bad_put_user
.long 2b,bad_put_user
.long 3b,bad_put_user
.previous
|
