blob: 92ca61233a8d22010074a103cc949f4ee6b2bd82 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
/* ld script to make m68k Linux kernel */
OUTPUT_FORMAT("elf32-m68k", "elf32-m68k", "elf32-m68k")
OUTPUT_ARCH(m68k)
ENTRY(_start)
SECTIONS
{
. = 0xE004000;
_text = .; /* Text and read-only data */
.text : {
*(.head)
*(.text)
*(.fixup)
*(.text.lock) /* out-of-line lock text */
*(.gnu.warning)
} = 0x4e75
.kstrtab : { *(.kstrtab) }
_etext = .; /* End of text section */
.data : { /* Data */
*(.rodata)
*(.data)
CONSTRUCTORS
. = ALIGN(16); /* Exception table */
__start___ex_table = .;
*(__ex_table)
__stop___ex_table = .;
__start___ksymtab = .; /* Kernel symbol table */
*(__ksymtab)
__stop___ksymtab = .;
}
/* End of data goes *here* so that freeing init code works properly. */
_edata = .;
. = ALIGN(8192); /* Init code and data */
__init_begin = .;
.text.init : { *(.text.init) }
.data.init : { *(.data.init) }
. = ALIGN(16);
__setup_start = .;
.setup.init : { *(.setup.init) }
__setup_end = .;
__initcall_start = .;
.initcall.init : { *(.initcall.init) }
__initcall_end = .;
. = ALIGN(8192);
__init_end = .;
.init.task : { *(init_task) }
.bss : { *(.bss) } /* BSS */
_end = . ;
.crap : {
/* Stabs debugging sections. */
*(.stab)
*(.stabstr)
*(.stab.excl)
*(.stab.exclstr)
*(.stab.index)
*(.stab.indexstr)
*(.comment)
*(.note)
}
}
|
